13.3. Where

13.3.1. Boolean operations
13.3.2. Filter on node label
13.3.3. Filter on node property
13.3.4. Regular expressions
13.3.5. Escaping in regular expressions
13.3.6. Case insensitive regular expressions
13.3.7. Filtering on relationship type
13.3.8. Property exists
13.3.9. Default true if property is missing
13.3.10. Default false if property is missing
13.3.11. Filter on null values
13.3.12. Filter on patterns
13.3.13. Filter on patterns using NOT
13.3.14. IN operator

If you need filtering apart from the pattern of the data that you are looking for, you can add clauses in the WHERE part of the query.

Figure 13.3. Graph


13.3.1. Boolean operations

You can use the expected boolean operators AND and OR, and also the boolean function NOT().

Query. 

MATCH n
WHERE n.name = 'Peter' XOR (n.age < 30 AND n.name = 'Tobias') OR NOT (n.name = 'Tobias' OR n.name="Peter")
RETURN n

This query shows how boolean operators can

Result

n
3 rows

Node[1]{age:25,name:"Tobias"}

Node[2]{age:34,name:"Peter"}

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.2. Filter on node label

To filter nodes by label, write a label predicate after the WHERE keyword using either the short WHERE n:foo or the long WHERE n LABEL [:foo, :bar] form

Query. 

MATCH n
WHERE n:Swedish
RETURN n

The "Andres" node will be returned.

Result

n
1 row

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.3. Filter on node property

To filter on a property, write your clause after the WHERE keyword. Filtering on relationship properties works just the same way.

Query. 

MATCH n
WHERE n.age < 30
RETURN n

The "Tobias" node will be returned.

Result

n
1 row

Node[1]{age:25,name:"Tobias"}


13.3.4. Regular expressions

You can match on regular expressions by using =~ "regexp", like this:

Query. 

MATCH n
WHERE n.name =~ 'Tob.*'
RETURN n

The "Tobias" node will be returned.

Result

n
1 row

Node[1]{age:25,name:"Tobias"}


13.3.5. Escaping in regular expressions

If you need a forward slash inside of your regular expression, escape it. Remember that back slash needs to be escaped in string literals

Query. 

MATCH n
WHERE n.name =~ 'Some\\/thing'
RETURN n

No nodes match this regular expression.

Result

n
0 row

(empty result)


13.3.6. Case insensitive regular expressions

By pre-pending a regular expression with (?i), the whole expression becomes case insensitive.

Query. 

MATCH n
WHERE n.name =~ '(?i)ANDR.*'
RETURN n

The node with name "Andres" is returned.

Result

n
1 row

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.7. Filtering on relationship type

You can put the exact relationship type in the MATCH pattern, but sometimes you want to be able to do more advanced filtering on the type. You can use the special property TYPE to compare the type with something else. In this example, the query does a regular expression comparison with the name of the relationship type.

Query. 

MATCH (n)-[r]->()
WHERE n.name='Andres' AND type(r)=~ 'K.*'
RETURN r

This returns relationships that has a type whose name starts with K.

Result

r
2 rows

:RelationshipTypeToken[name:KNOWS, id:0][0] {}

:RelationshipTypeToken[name:KNOWS, id:0][1] {}


13.3.8. Property exists

To only include nodes/relationships that have a property, use the HAS() function and just write out the identifier and the property you expect it to have.

Query. 

MATCH n
WHERE HAS (n.belt)
RETURN n

The node named "Andres" is returned.

Result

n
1 row

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.9. Default true if property is missing

If you want to compare a property on a graph element, but only if it exists, use the nullable property syntax. You can use a question mark if you want missing property to return true, like:

Query. 

MATCH n
WHERE n.belt? = 'white'
RETURN n
ORDER BY n.name

This returns all nodes, even those without the belt property.

Result

n
3 rows

Node[3]{age:36,name:"Andres",belt:"white"}

Node[2]{age:34,name:"Peter"}

Node[1]{age:25,name:"Tobias"}


13.3.10. Default false if property is missing

When you need missing property to evaluate to false, use the exclamation mark.

Query. 

MATCH n
WHERE n.belt! = 'white'
RETURN n

No nodes without the belt property are returned.

Result

n
1 row

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.11. Filter on null values

Sometimes you might want to test if a value or an identifier is null. This is done just like SQL does it, with IS NULL. Also like SQL, the negative is IS NOT NULL, although NOT(IS NULL x) also works.

Query. 

START a=node(1), b=node(3, 2)
MATCH a<-[r?]-b
WHERE r IS NULL RETURN b

Nodes that Tobias is not connected to are returned.

Result

b
1 row

Node[2]{age:34,name:"Peter"}


13.3.12. Filter on patterns

Patterns are expressions in Cypher, expressions that return a collection of paths. Collection expressions are also predicates — an empty collection represents false, and a non-empty represents true.

So, patterns are not only expressions, they are also predicates. The only limitation to your pattern is that you must be able to express it in a single path. You can not use commas between multiple paths like you do in MATCH. You can achieve the same effect by combining multiple patterns with AND.

Note that you can not introduce new identifiers here. Although it might look very similar to the MATCH patterns, the WHERE clause is all about eliminating matched subgraphs. MATCH a-[*]->b is very different from WHERE a-[*]->b; the first will produce a subgraph for every path it can find between a and b, and the latter will eliminate any matched subgraphs where a and b do not have a directed relationship chain between them.

Query. 

MATCH tobias, others
WHERE tobias.name='Tobias' AND (others.name='Andres' OR others.name='Peter') AND tobias<--others
RETURN others

Nodes that have an outgoing relationship to the "Tobias" node are returned.

Result

others
1 row

Node[3]{age:36,name:"Andres",belt:"white"}


13.3.13. Filter on patterns using NOT

The NOT() function can be used to exclude a pattern.

Query. 

START persons=node(*), peter=node(2)
WHERE NOT (persons-->peter)
RETURN persons

Nodes that do not have an outgoing relationship to the "Peter" node are returned.

Result

persons
2 rows

Node[1]{age:25,name:"Tobias"}

Node[2]{age:34,name:"Peter"}


13.3.14. IN operator

To check if an element exists in a collection, you can use the IN operator.

Query. 

MATCH a
WHERE a.name IN ['Peter' , 'Tobias']
RETURN a

This query shows how to check if a property exists in a literal collection.

Result

a
2 rows

Node[1]{age:25,name:"Tobias"}

Node[2]{age:34,name:"Peter"}